dotter

uml (4030B)

---

 #!/usr/bin/awk -f
 
 function is_class( identifier ) {
 	return identifier == "struct" || identifier == "class";
 }
 
 function print_ft_name() {
 	printf( "\"" );
 	for( i = 2; i < NF; ++i )
 	{
 		printf( "%s ", $i );
 	}
 	printf( "%s\"", $NF );
 }
 
 function end_class() {
 	if( class != "" )
 	{
 		printf( "}\"\n]\n" );
 		prev_class = class;
 		class = "";
 	}
 	class_type = "";
 	inside = "";
 	fields_max = 0
 	fields_cur = 0
 }
 
 function fun( overload ) {
 	if( inside != "fun" )
 	{
 		printf( "|" );
 		inside = "fun";
 	}
 	printf( "%s %s(", scope, $3 )
 	for( i = 4; i <= NF; ++i )
 	{
 		gsub( ":", " ", $i );
 		printf( "%s%s", i == 4 ? "" : ", ", $i );
 	}
 	printf( "): %s %s\l", $2, overload );
 }
 
 function relation( to, tail, head, label, multiplicity ) {
 	printf( "%s -> %s [ dir = \"both\", arrowtail = \"%s\", arrowhead = \"%s\"", prev_class, to, tail, head );
 	if( label != "" )
 	{
 		printf( ", label = \"%s\"", label );
 	}
 	if( multiplicity != "" )
 	{
 		if( multiplicity ~ /[0-9]*:[0-9n]*/ )
 		{
 			split( multiplicity, labels, ":" );
 			printf( ", taillabel = \"%s\", headlabel = \"%s\"", labels[1], labels[2] );
 		}
 		else
 		{
 			printf( ", headlabel = \"%s\"", multiplicity );
 		}
 	}
 }
 
 function close_relation() {
 	printf( " ];\n" );
 }
 
 function depends( type ) {
 	end_class();
 	relation( $2, "none", "vee", type );
 	printf( " style = \"dotted\"" );
 	close_relation();
 }
 
 BEGIN {
 	printf( "digraph %s\n{\n", FILENAME );
 	class = "";
 	prev_class = "";
 	class_type = "";
 	inside = "";
 }
 
 $0 ~ "^[ \t]*private"   { scope = "[-]"; }
 $0 ~ "^[ \t]*protected" { scope = "[#]"; }
 $0 ~ "^[ \t]*public"    { scope = "[+]"; }
 $0 == "package"   { scope = "[~]"; }
 
 $1 == "splines" {
 	end_class();
 	printf( "splines = %s;\n", $2 );
 }
 
 $1 == "package_font" {
 	end_class();
 	printf( "fontname = " );
 	print_ft_name();
 	printf( ";\n" );
 }
 
 $1 == "class_font" {
 	end_class();
 	printf( "node [fontname = " );
 	print_ft_name();
 	printf( "];\n" );
 }
 
 $1 == "link_font" {
 	end_class();
 	printf( "edge [fontname = " );
 	print_ft_name();
 	printf( "];\n" );
 }
 
 # TODO: for templates, it would be better to allow providing types as well
 $1 == "enum" || $1 == "bitfield" || $1 == "template" || is_class( $1 ) {
 	end_class();
 
 	if( NF == 3 )
 	{
 		fields_max = $3
 		fields_cur = 0
 	}
 	scope = "[ ] ";
 	printf( "\n\n" );
 	class = $2;
 	class_type = $1;
 	special = ""; # for templates, enums, bitfields, structs (why not)...
 	if ( class_type != "class" )
 	{
 		scope = "";
 		special = "«" class_type;
 		if ( fields_max != 0 )
 		{
 			special = special "(" fields_max ")";
 		}
 		special = special "»";
 	}
 	printf( "%s\n[\n\tshape=\"record\";\n\tlabel=\"{%s %s", class, class, special );
 }
 
 $1 == "fun" {
 	fun( "" );
 }
 
 $1 == "virtual" {
 	fun( "[[VIRT]]" );
 }
 
 $1 == "abstract" {
 	fun( "[[ABST]]" );
 }
 
 $1 == "var" {
 	if( inside != "var" )
 	{
 		printf( "|" );
 		inside = "var";
 	}
 	printf( "%s%s: %s", scope, $3, $2 );
 	if( NF == 4 )
 	{
 		printf( " = %s", $4 );
 	}
 	printf( "\l" );
 }
 
 $1 == "val" {
 	if( inside != "val" )
 	{
 		printf( "|" );
 		inside = "val";
 	}
 	error = "";
 	if ( fields_max != 0 )
 	{
 		++fields_cur;
 		if ( fields_cur > fields_max )
 		{
 			error = "EE: "
 		}
 	}
 	if ( is_class( class_type ) )
 	{
 		printf( "%s%s %s", error, scope, $2 );
 	}
 	else
 	{
 		if ( fields_max != 0 )
 		{
 			printf( "%s%d: %s", error, fields_cur, $2 );
 		}
 		else
 		{
 			printf( "%s%s", error, $2 );
 		}
 	}
 	printf( "\l" );
 }
 
 $1 == "inherit" {
 	end_class();
 	relation( $2, "none", "empty" );
 	close_relation();
 }
 
 $1 == "associate" {
 	end_class();
 	relation( $2, "none", "vee", $3, $4 );
 	close_relation();
 }
 
 $1 == "aggreg" {
 	end_class();
 	relation( $2, "odiamond", "vee", $3, $4 );
 	close_relation();
 }
 
 $1 == "compose" {
 	end_class();
 	relation( $2, "diamond", "vee", $3, $4 );
 	close_relation();
 }
 
 $1 == "depends" {
 	depends( "" );
 }
 
 $1 == "friend" {
 	depends( "friend" );
 }
 
 $1 == "package" {
 	end_class();
 	printf( "\nsubgraph cluster%s\n{\nlabel = \"%s\" ", $2, $2 );
 }
 
 $1 == "endpackage" {
 	end_class();
 	printf( "}\n" );
 }
 
 END {
 	end_class();
 	printf( "}\n" );
 }